MikroTik: Hoe de interface volgens een schema uit te schakelen (in te schakelen)

We zullen verschillende manieren analyseren om de MikroTik-netwerkinterface uit te schakelen (in te schakelen) of het internet uit te schakelen, volgens een schema: firewallregel, NAT, MikroTik-taakplanner of MikroTik-script.

Inhoud

1. Firewallregel: hoe u een interface volgens een schema kunt uitschakelen (inschakelen)
2. NAT: hoe u internet volgens een schema kunt toestaan (weigeren)
3. Scheduler: interface volgens schema uitschakelen (inschakelen)
4. MikroTik-script: hoe de interface uit te schakelen (in te schakelen)

Firewallregel: hoe u een interface volgens een schema kunt uitschakelen (inschakelen)

Om de interface volgens een schema uit of uit te schakelen, kunt u de instelling Firewall-regel op het tabblad Extra gebruiken.

⚠️ Om de regel te laten werken, moet de interface de hoofdinterface (main) zijn.

Bijvoorbeeld: we beperken de werking van de WiFi-interface (wlan2-5GHz) tijdens niet-werkuren, van 19:00 tot 07:00 uur.

Maak een regel:

[IP] -> [Firewall] -> [Filter Rules] -> [+] -> [General: Chain=forward, In. interface=wlan2-5GHz; Extra: Time=19:00:00-07:00:00; Comment="Blocking traffic on the interface, according to the schedule."]

in terminal:

/ip firewall filter add action=reject chain=forward in-interface=wlan2-5GHz reject-with=icmp-network-unreachable time=9h-7h,sun,mon,tue,wed,thu,fri,sat comment="Blocking traffic on the interface, according to the schedule."

Als u de werking van de interface op zaterdag en zondag (volledige dag) wilt uitschakelen, stelt u de tijdwaarden in:

[IP] -> [Firewall] -> [Filter Rules] -> [+] -> [General: Chain=forward, In. interface=wlan2-5GHz; Extra: Time=00:00:00-1d 00:00:00, Days=sun, sat; Comment="Blocking traffic on the interface, according to the schedule."]

in terminal:

/ip firewall filter add action=drop chain=forward in-interface=wlan2-5GHz time=0s-1d,sun,sat comment="Blocking traffic on the interface, according to the schedule."

NAT: hoe u internet volgens een schema kunt toestaan (weigeren)

U kunt geplande internettoegang weigeren (of toestaan) met behulp van de NAT-instelling (maskeraderegel).

Bewerk de masquerade regel, onder het tabblad Extra:

[IP] -> [Firewall] -> [NAT] -> [Extra: Time=19:00:00-07:00:00, Days: mon,tue,wed,thu,fri; Comment="Rule runs on schedule."]

in terminal:

/ip firewall nat add action=masquerade chain=srcnat out-interface-list=ExternalInterfaces time=8h-20h,mon,tue,wed,thu,fri comment="Rule runs on schedule."

Scheduler: interface volgens schema uitschakelen (inschakelen)

Schakel de wifi wlan2-5GHz-interface uit na 20:00:00 met MikroTik Scheduler:

[System] -> [Schedule] -> [+] -> [Name: "Interface: Disable WiFi"; Start Time: 20:00:00; Interval: 1d 00:00:00; Policy: read, write, policy, test; text: "[/interface set wlan2-5GHz disabled=yes]"; Comment: Disable the interface at the specified time]

in terminal:

/system scheduler add name="Interface: Disable WiFi" start-date=feb/22/2021 start-time=20:00:00 interval=1d on-event="[/interface set wlan2-5GHz disabled=yes]" policy=read,write,policy,test comment="Disable the interface at the specified time"

Schakel de WiFi wlan2-5GHz-interface in vanaf 08:00:00 met MikroTik Scheduler:

[System] -> [Schedule] -> [+] -> [Name: "Interface: Enable WiFi"; Start Time: 20:00:00; Interval: 1d 00:00:00; Policy: read, write, policy, test; text: "[/interface set wlan2-5GHz disabled=no]"; Comment: Disable the interface at the specified time]

in terminal:

/system scheduler add name="Interface: Enable WiFi" start-date=feb/22/2021 start-time=08:00:00 interval=1d on-event="[/interface set wlan2-5GHz disabled=no]" policy=read,write,policy,test comment="Enable the interface at the specified time"

MikroTik-script: hoe de interface uit te schakelen (in te schakelen)

U kunt de interface ook uitschakelen (of inschakelen) met behulp van het MikroTik-script en de Taakplanner.

Maak een script

Specificeer de volgende variabelen in het script:

1. InterfaceName – interfacenaam (in het voorbeeld wlan2-5GHz);
2. StartEnableTime – tijd, vanaf welke de interface moet worden ingeschakeld (in het voorbeeld 08:00:00);
3. EndEnableTime – tijd, waarna de interface moet worden uitgeschakeld (in het voorbeeld 20:00:00).

[System] -> [Scripts] -> [+] -> [Name: WorkTimeInterface] -> [Policy: read, write, test, policy]

Scriptcode:

# Name: WorkTimeInterface v1
# Description: Enable or disable the selected interface on a schedule.
# Author: Yun Sergey [MHelp.pro] © 2021
# License: GPL-3.0 License
# Description, purpose and questions: https://mhelp.pro/mikrotik-how-to-disable-enable-the-interface-on-a-schedule/
# More scripts Mikrotik: https://mhelp.pro/tag/mikrotik-scripts/
# Verified: RouterBOARD 952Ui-5ac2nD, RouterOS 6.48.1 (stable)

:local InterfaceName wlan2-5GHz;
:local StartEnableTime [:totime "08:00:00"];
:local EndEnableTime [:totime "20:00:00"];

:local StatusInterface [/interface get $InterfaceName disabled];
:local CurrenTime [/system clock get time];

#:log info "Script WorkTimeInterface running. Interface $InterfaceName disabled: $StatusInterface.";

:if ( $StartEnableTime < $CurrenTime and $CurrenTime < $EndEnableTime) do={
    #:log info "Script WorkTimeInterface: work time.";
    :if  ($StatusInterface) do={
        [/interface set $InterfaceName disabled=no];
        :log info "Script WorkTimeInterface: interface $InterfaceName was disabled, enabled the interface.";
    } else={
        #:log info "Script WorkTimeInterface: skip enable interface, $InterfaceName already enabled.";
    };

} else={
    #:log info "Script WorkTimeInterface: not work time";
    :if  (!$StatusInterface) do={
        [/interface set $InterfaceName disabled=yes];
        :log info "Script WorkTimeInterface: interface $InterfaceName was enabled, disabled the interface."
    }
}
#:log info "Script WorkTimeInterface finished. Interface $InterfaceName disabled: $StatusInterface.";

Als het script niet of niet correct werkt, verwijder het commentaar dan bij de regels :log (verwijder het # -symbool voor het begin van de regel) en controleer het MikroTik-logboek wanneer het script start.

Voeg script toe aan Scheduler

Om het script uit te voeren, heb je toestemming nodig: read, write, test, policy.

[System] -> [Schedule] -> [+] -> [Name: "Interface: Enable/Disable WiFi"; Start Time: 00:00:50; Interval: 00:15:00; Policy: read, write, policy, test; text: "[/system script run WorkTimeInterface]"; Comment: "Run script Enable/Disable interface"]

---

? Hoe u de MikroTik-interface volgens een schema kunt uit te schakelen (in te schakelen) of toegang tot internet op tijd kunt (weigeren), werd in dit artikel besproken. Ik hoop dat je een geschikte manier hebt gekozen om de staat van de interface te beheren. Als u echter problemen ondervindt tijdens het instellen, kunt u in de opmerkingen schrijven. Ik zal proberen te helpen.

Het script wordt gecontroleerd: hAP ac lite [RouterBOARD 952Ui-5ac2nD], RouterOS 6.48.1 (stable).